Trigger event onRelease of button

Question

I am using the EasyButton library to detect button presses on an arduino.

I want do execute a function when the user

1. Presses a button
2. Presses and holds a button
3. Releases a button

Detecting when a user presses or holds a button is straight forward

#include <Arduino.h>
#include <EasyButton.h>
# define BUTTON_PIN 2;
EasyButton button(BUTTON_PIN);
void onPressedCallback() {
  Serial.println("Button was pressed and released");
}
void onHoldCallback() {
  Serial.println("Button was pressed and held");
}
void setup() {
  button.begin();
  button.onPressed(onPressedCallback);
  button.onPressedFor(buttonHoldDuration, onHoldCallback);
}

The easyButton library has the following events

• onPressed
• onPressedFor
• onSequence

It has the following states

• isPressed
• isReleased
• wasPressed
• wasReleased
• pressedFor
• releasedFor

How would you trigger an event when a button is 'released'?

Full Documentation

https://easybtn.earias.me/docs/on-single-press-api

What I've tried

1. Check the state from inside an event

void onHoldCallback() {
  while (button.isPressed() {
     Serial.println("you are still holding the button");
  }
  Serial.println("Button was released");
}

This unfortunately creates an infinite loop since the button state is never refreshed (button.begin();)

Additional Resources

• https://github.com/evert-arias/EasyButton/tree/main/examples
• Source code for the system interupt https://github.com/evert-arias/EasyButton/blob/4e818410252e9518564fc55f8d4a976fac70a9b2/src/EasyButton.cpp#L55-L82

Answer 1

The onPressed() event Triggers a callback function when the button has been pressed and released.

Here's a test sketch to show what I mean. I've also added a function you could use to detect the moment the button is first pressed.

#include <EasyButton.h>
// EasyButton(uint8_t pin, 
//            uint32_t debounce_time = 35, 
//            bool pullup_enable = true, 
//            bool active_low = true)
EasyButton button(2);
void onReleased(){
  Serial.println("Button Releast");
}
void firstPressed(){
  Serial.println("First Pressed");
}
void setup(){
// Test output to serial monitor.
  Serial.begin(9600);
// Initialize the button.
  button.begin();
// Add the callback function to be called
  // when the button is pressed then released.
  // NOTE: This function is only called AFTER
  // the button has been released.
  button.onPressed(onReleased);
}
void loop(){
// Continuously read the status of the button.
  button.read();
// Call a function the moment the button is pressed.
  if(button.wasPressed()){
    firstPressed();
  }
}

Answer 2

Just check the easyButton state in your loop code and run your functions as required. The library already has the events you need, no point rolling your own. It's best just to set a variable or flag in event code so it returns quickly, then deal with the results in the main loop. The easyButton library has done most of that work for you.

Answer 3

Origionally I started with the EasyButton library, but when I wasn't able to get it working I switched to the madleech/Button@^1.0.0 library and got the following working.

Note that this depends on polling which could definitly be improved.

While this deviates from the original question, I feel it is worth sharing for anyone else who wants a working but (less than ideal) solution.

#include <Arduino.h>
#include <Button.h>
Button button1(2);
unsigned long buttonCheckMillis;
void setup()
{
  buttonCheckMillis = millis();
  button1.begin();
}
void loop()
{
  if (button1.toggled()) {
    // User pressed the button
    if (button1.read() == Button::PRESSED) {
      Serial.println("Button Pressed");
    }
    // User released the button
    else {
      Serial.println("Button Released");
    }
  }
  // Poll every 100 milliseconds to see if user is still holding button
  if (millis() - buttonCheckMillis > 100) {
    buttonCheckMillis = millis();
    if (button1.read() == Button::PRESSED) {
      Serial.println("Button Held");
    }
  }
}