ATtiny88 ADC reference voltage setting

Question

I'm writing a simple application that reads voltage from analog input 0. Here is the code:

#define OUT 5
#define ADC 0

void setup() {
  ADMUX &= (0<<REFS0); //Setting reference voltage to internal 1.1V
}

// the loop routine runs over and over again forever:
void loop() {
  // read the input on analog pin 0:
  int sensorValue = analogRead(0);
  float voltage = sensorValue * (1.1 / 1023.0);
  if (voltage>0.5) {
    digitalWrite(OUT,HIGH);
  } else {
    digitalWrite(OUT,LOW);
  }
}

When I apply 1 V on ADC0, the OUT pin is low. Seems like the reference voltage is not set properly. When I set VREF to VCC (5V), everything works fine.

I cannot find the mistake. Would appreciate any help:)

Edit:

Link to datasheet: http://www.atmel.com/images/doc8008.pdf

score 1 · Answer 1 · edited Apr 13 '17 at 12:50

The statement

ADMUX &= (0<<REFS0);

AND's the current value of ADMUX with zero, resulting in a zero value, and stores it into ADMUX.

To clear the REFS0 bit in ADMUX without affecting the rest of it, one generally would instead say

ADMUX &= ~(1<<REFS0);

which will AND its value with the complement of 1<<REFS0.

However, you should use the statement

analogReference(INTERNAL);

instead of setting ADMUX directly. One of the first statements executed in the analogRead() source code is

ADMUX = (analog_reference << 6) | (pin & 0x07);

which overrides reference selections made by just changing ADMUX.

Parameters INTERNAL and DEFAULT to analogReference() select either the 1.1 V internal bandgap reference or the default analog reference, Vcc.

Edit 1: If you replace ADMUX &= (0<<REFS0) with analogReference(INTERNAL) in setup and it still doesn't work, you will need to apply some more-powerful debugging aids. For example, check that you got the sketch to correctly compile and that you uploaded it ok. Check that AVCC is connected to Vcc, preferably through a low-pass filter, as noted in datasheet sections §1.1.2 and §17.9, “Analog Noise Canceling Techniques”. Then, try several voltage inputs to see at what level the LED comes on. If it doesn't ever come on, look for LED problems using a simple sketch like Blink. If it comes on consistently at some input voltage, work out what reference is being applied.

Edit 2: Apparently the source code of analogRead() is different for ATtiny parts vs others. The code that I see for it in ... /arduino/avr/cores/arduino/wiring_analog.c [your path may differ] is like the following (I've elided some comments and blank lines).

uint8_t analog_reference = DEFAULT;
void analogReference(uint8_t mode) {
  analog_reference = mode;
}

int analogRead(uint8_t pin) {
  #if defined( CORE_ANALOG_FIRST )
    if ( pin >= CORE_ANALOG_FIRST ) pin -= CORE_ANALOG_FIRST; // allow for channel or pin numbers
  #endif
  ADC_SetVoltageReference( analog_reference );
  ADC_SetInputChannel( pin );
  ADC_StartConversion();
  while( ADC_ConversionInProgress() );
  return( ADC_GetDataRegister() );
}

Some ADC_... functions and constants are defined in ... avr/cores/tiny/core_adc.h; and which definition of ADC_SetVoltageReference() is used depends on conditional compilation. For a definitive check on how analogReference() is defined for your part, look for analogReference() within the assembly listing of your program. Obtain that listing as explained in several Arduino SE answers, for example in the “Making assembly listings” paragraph near the end of my answer to question #33033. Also, a forum.arduino.cc thread from late April 2016 has some discussion of reading ADC inputs on tinys; I don't know if it's relevant.

score 0 · Answer 2 · answered Jan 18 '17 at 22:21

0

In your setup section, you want to set or clear all relevant bits in admux.

answered Jan 18 '17 at 22:21

dannyf

2,813
11
13

ATtiny88 ADC reference voltage setting

2 Answers2